Membuat Soal Interaktif dengan Excel

Berawal dari tugas-tugas Anakku yang perlu dikoreksi. Yang cukup menyita waktu. Maka Kami berinisiatif membuat sebuah latihan soal dengan Mo.Excel. Sehingga Anakku tau mana yang jawabannya salah. Sehingga bisa langsung diperbaiki. Serperti inilah tahapannya.
1. Buat sheet dengan nama kunci (di sheet ini Kita akan meletakkan kunci jawaban dari soal-soal yang kita buat nantinya). tablenya juga cukup sederhana tinggal buat Kolom No. Dan Jawaban. seperbi gambari dibawah

kunci

Disini saya cuma buat sampai 17, kalau Rekan-rekan mau nambah silahkan tambah sendiri yaa.
2. table tersebut Kita format sebagai table dengan cara :

• Blog Cell B4:C21
• Klik Ribbon Menu Format As Table (pilih layout table sesuai dengan selera Anda)

3. Langkah berikutnya, Kita masuk ke sheet berikutnya yaitu sheet Soal

• buat 4 kolom dengan nama no;soal;jawaban;koreksi (lihat gambar dibawah! Sementara contek abis ajah. Ikuti persis seperti di gambar. Nanti baru kembangkan sendiri)

              

              Saya memulai dari Cell A3

• Setelah buat persis seperti itu kemudian table tersebut kita format sebagai Table (untuk mempermudah membuat referensi) langkahnya sama seperti di Sheet kunci. Blog seluruh table kemudian klim Ribbon Menu Format As Table (pilih layout sesuai selera)
• Setelah table kita beri nama, selanjutnya kita akan memasukkan sedikit fungsi di cell D4 adapun rumusnya adalah sebagai berikut :

=IFERROR(IF(VLOOKUP(Table1[[#This Row];[no]];Table2;2;0)=Table1[[#This Row];[jawaban]];”Benar”;IF(Table1[[#This Row];[jawaban]]=”";”silahkan pilih jawaban”;”Salah”));”")

catatan : di komputer Saya pemisah formula menggunakan ; (titik koma),  mungkin dikomputer Rekan-rekan berbeda biasanya , (koma) coba disesuaikan saja

saya akan coba pecah Formulanya

=IFERROR( //jika rumus error maka yang dihasilkan adalah “” (kosong)

IF(

VLOOKUP(Table1[[#This Row];[no]];Table2;2;0)=Table1[[#This Row];[jawaban]];”Benar”;

//Mencocokan data di Table1(kunci) apakah soal no X jawabannya sama dengan kunci no X ? Jika sama hasilkan “Benar”

IF( //jika tidak

Table1[[#This Row];[jawaban]]=”";”silahkan pilih jawaban”;”Salah”

//Jika Cell Jawaban Kosong maka hasilkan “silahkan pilih jawaban” jika tidak “salah”

)

)

;”")

formula tersebut adalah formula koreksi. Yang akan mencocokkan kunci jawaban dengan jawabannya apakah benar/salah.

Selanjutnya Kita akan membuat Efek, jika jawaban salah maka seluruh bari akan berwarna merah dengan teks berwarna putih. Langkahnya adalah

• letakkan kursor di salah satu baris kemudian tekan Ribbon menu Home-Condition Formating-New Rule format sesuai dengan gambar dibawah ini

conditional

setelah tekan Ok lakukan sama seperti gambar di bawah ini

di kolom applies To ketikkan = Table2 (table2 adalah nama table dari sheet soal, jika berbeda sesuaikan. Tapi kalau langkahnya sama dari awal sepertinya tidak berbeda. Tekan oke
Sekarang silahkan dicoba. Buat beberapa soal. Dan buat kunci jawabannya. Coba dites jika soal jawabannya salah apa yang akan terjadi. Untuk membandingkan dengan yang anda buat silahkan sedot file ini soal_pilihan

Scanning Jawaban Pilihan Ganda Pake Excel

Scanning Jawaban Pilihan Ganda Pake Excel

Sebagai guru, saya seringkali mengadakan ujian bagi siswa dan siswi. Nah, pekerjaan tambahan kalau lagi musim ujian adalah mengkoreksi pekerjaan siswa. 
Kali ini saya ingin membagi pengalaman koreksi pilihan ganda dengan Excel (semacam scanning LJK), tapi jawaban siswa kita masukkan secara manual. Sangat cocok untuk digunakan sebagai analisis butir soal nantinya.
Misal kita buat seperti gambar di bawah ini:

Tugas kita adalah meghitung Jumlah Soal, berdasarkan kunci jawaban yang ada, lalu menghitung jumlah jawaban tiap siswa yang benar.


Untuk menghitung jumlah soal tinggal menuliskan rumus di sel E11. Rumusnya : =LEN(D11)-(LEN(D11)-LEN(SUBSTITUTE(D11,"-",""))).


Lalu untuk Skor tiap Soal dan Nilai Maksimal silahkan kita isi sendiri sesuai keinginan kita.


Tahap inti dari tugas kita adalah menghitung berapa jumlah jawaban benar tiap siswa, dimulai dari sel E14. 
Sebenarnya banyak sekali kombinasi rumus yang bisa kita gunakan, baik menggunakan sel bantuan maupun tanpa sel bantuan. Salah satu kombinasi rumus yang bisa kita tulis di sel E14 adalah :


=SUM((MID(SUBSTITUTE(D14,"-",""),ROW(INDIRECT("1:"&$E$11)),1)=MID(SUBSTITUTE($D$11,"-",""),ROW(INDIRECT("1:"&$E$11)),1))*1)


Ingat...!
Rumus di atas adalah rumus Array. Kalau rumus biasa, setelah selesai nulis kita tekan Enter, nah, untuk rumus Array, setelah selesai nulis kita tekan Ctrl+Shift+Enter secara bersamaan.
Rumus ditulis langsung dalam satu baris tanpa spasi.


Lalu kita kopikan ke bawah sampai sejumlah siswa.


Rumusnya panjang amat ya...? berikut penjelasan satu persatu dari rumus di atas.


MID
mengambil sebagian karakter tertentu dalam satu sel. Jadi kita ambil satu per satu masing-masing huruf dari jawaban siswa. MID dalam rumus di atas ada dua, yakni untuk sel D14 dan sel D11. Karena kita ingin membandingkan apakah masing-masing huruf jawaban siswa sama dengan kunci jawaban.


SUBSTITUTE
Fungsi ini untuk mengganti karakter tertentu dari teks. Dalam rumus di atas, kita akan mengganti karakter "-" dengan karakter "". Artinya kita menghilangkan karakter "-" dari jawaban siswa.




INDIRECT
Rumus ini untuk mengatasi banyaknya soal yang mungkin tidak sama. Pembahasan tentang rumus INDIRECT bisa dilihat di sini

ROW
Fungsi ROW untuk menampilkan nomor baris. ROW(A1) hasilnya adalah 1. ROW(A2) hasilnya ya 2. ROW(1:2) hasilnya adalah data array {1,2}.


*1
Mengapa harus dikalikan satu?
Ya, karena dengan fungsi MID di atas, kita mengambil satu persatu huruf mulai nomor 1 sampai nomor 25, dan kita membandingkan dengan Kunci Jawaban satu per satu juga. Hasil perbandingan akan bernilai TRUE atau FALSE. Jika jawaban siswa "A" dan kunci "A" maka hasilnya TRUE. Ternyata di Excel TRUE sama dengan 1, sedang FALSE sama dengan 0. Agar data Bolean TRUE dan FALSE tadi berubah jadi angka biasa, maka kita kalikan dengan 1. Sehingga untuk jawaban siswa absen 1, akan menghasilkan data array {1,1,1,1,1,1,0,0,0,0,0,1,0,1,1,1,1,1,0,0,0,0,1,1,1}.


SUM
Menjumlah data array di atas. Yakni 15.


Untuk Jumlah jawaban salah, kita tinggal mengurangi jumlah soal dengan jumlah jawaban benar : =$E$11-E14.


Untuk jumlah nilai, tinggal mengalikan Jumlah jawaban benar dengan skor tiap item : =E11*$F$11.


Masih bingung?
Bagi yang agak pemula, penggunaan rumus Array memang sedikit membuat pusyiiingggg. Gak majalah, eh Gak Masalah, seiring dengan waktu sambil terus kita belajar, segalanya akan makin mudah. 
Keuntungan menggunakan array formula ini, kita bisa melakukan sesuatu yang tidak bisa dilakukan dengan menggunakan rumus biasa. Penjelasan secara rinci tentang Array Formula bisa dilihat di sini



Sekian dulu, semoga bermanfaat

File contoh bisa didownload di sini